;;; Joiners/Parters mIRC script
;;; Created by Adonai @ irc.quakenet.org
;;; Created for #3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034, because so many people like to join then part that channel.
;;; This was created for that channel only, and you'd better know a little something about programming in mIRC if you wish to run this correctly.
;;; Maybe I'll expand this script more if I get enough requests to, or if you make better changes and /msg me them. ;)

;;; First, set the channel you wish to run this script in. It would be a good idea to set this before loading it in mIRC
on *:start: {
  %jps.channel = #3.141592653589793238462643383279502884197169399375105820974944592307816406286208998628034
}
on *:load: {
  %jpsx = 0
}

;;; When someone joins, we set a temporary variable for 10 minutes on their nick.
on *:join:%jps.channel {
  set -u600 %jpsnik. $+ $nick 1
}

;;; Sometimes people we know will get voiced/op'd, then part. We should get rid of them, we don't want them joining the club!
;;; You could take out the voice if you auto-voice people as they enter.
on *:voice:%jps.channel {
  if (%jpsnik. [ $+ [ $nick ] ]) {
    unset %jpsnik. [ $+ [ $nick ] ]
  }
}
on *:op:%jps.channel {
  if (%jpsnik. [ $+ [ $nick ] ]) {
    unset %jpsnik. [ $+ [ $nick ] ]
  }
}

;;; This checks to see if the parted nick is a join/parter, that bastard. It sends them a small hate message, you can change it up though.
on *:part:%jps.channel {
  if (!%jpsdup. [ $+ [ $nick ] ]) {
    if (%jpsnik. [ $+ [ $nick ] ]) {
      inc %jpsx 1
      .msg $nick Congratulations $nick $+ ! You are person number %jpsx to be added to the joiners/parters club of pi!
      set -u600 %jpsdup. $+ $nick 1
    }
  }
}

;;; This is optional... if someone in the channel types "!jp" it will give them the current count.
on *:text:!jp*:%jps.channel {
  if (!%jpsnof. [ $+ [ $chan ] ]) {
    set -u60 %jpsnof. $+ $chan 1
    jps
  }
}

;;; This helps keep the stupid join/parter from querying you back suddenly.
;;; I found a lot of scripts are equiped with a feature to auto-respond to you.
;;; And some people just want to yell at you in German... anyway, you can change this up how you please.
on ^1:open:?:*: {
  if (%jpsnik. [ $+ [ $nick ] ]) {
    echo $nick $+ 's stupid query was blocked.
    if (!%jpsnofq. [ $+ [ $nick ] ]) {
      set -u600 %jpsnofq. $+ $nick 1
      ;;;      .msg $nick Sorry, $nick $+ , I just blocked your query. Most likely you were using your stupid script to try and respond to me about how busy you are and blah blah blah, or maybe just to yell at me. Either way, I didn't read it. And thank you for joining the club!
      halt
    }
    halt
  }
}

;;; Below are the aliases and popups...
alias jps {
  %message = There are %jpsx people in the joiners/parters club of pi. Bastards!
  .raw PRIVMSG %jps.channel : $+ %message | echo -t $chan <@ $+ $me $+ > %message
}
alias jpsadd1 {
  inc %jpsx 1
  echo Added 1 to it, sir! The current count: %jpsx $+ .
}
alias jpssub1 {
  dec %jpsx 1
  echo Subtracted 1 from it, sir! The current count: %jpsx $+.
}
alias ijps {
  echo The current count: %jpsx $+.
}
menu channel {
  -
  Join/Parters
  .say joins/parts { jps }
  .echo joins/parts { ijps }
  .add 1 { jpsadd1 }
  .subtract 1 { jpssub1 }
  -
}